(set @app-name "Betty")

(set #wrongversion
(cat "You have an old version of the program 'Installer' "
     "on your Amiga!\n\nThe installation procedure needs at least Installer 42.9.\n\n"
     "Please check your configuration!"
))

(set #welcome
(cat "Welcome to the the Installation of the Betty GUI System!"
))

(if (< @installer-version 2752521)
	(
		(message #wrongversion)
		(exit (quiet))
	)
)

(welcome #welcome)

(set #instmode
	(askchoice
		(prompt "What do you want to do?")
		(help @askchoice-help)
		(choices "Install" "Uninstall")
		(default 0)
	)
)

(if (= #instmode 0)

(
;Install
(complete 0)

(set #classdir
	(askdir
		(prompt "Select the dir where Betty should be installed. (A dir named 'Betty' will be created)")
		(help @askdir-help)
		(default "sys:")
	)
)

(makedir (tackon #classdir "Betty")
	(infos)
)

(set #classdir (tackon #classdir "Betty"))
(set @default-dest #classdir)

(makedir (tackon #classdir "Classes")
	(infos)
)

(makedir (tackon #classdir "S")
	(infos)
)

(working "Un-Archiving all_cl.lha")

(run ("lha x all_cl.lha %s" (tackon #classdir "Classes/"))
)

(complete 75)

(working "Un-Archiving handlers_lib.lha")

(run ("lha x handlers_lib.lha %s" ("%s/" #classdir))
)

(complete 80)

(working "Un-Archiving errorserv_lib.lha")

(run ("lha x errorserv_lib.lha %s" ("%s/" #classdir))
)

(complete 85)

(working "Un-Archiving classerv_lib.lha")

(run ("lha x classerv_lib.lha %s" ("%s/" #classdir))
)

(complete 90)

(working "Copying classerver files")

(copyfiles
	(source (tackon #classdir "classerv/classname.map"))
	(dest (tackon #classdir "S"))
)

(copyfiles
	(source (tackon #classdir "classerv/globalclass.map"))
	(dest (tackon #classdir "S"))
)

(makeassign "BettyHome" #classdir)

(run "assign libs: BettyHome:libs add")

(run "assign libs: BettyHome:classes add")

(run "assign s: BettyHome:s add")

(run "bettyhome:errorserv/errorserver")
(run "bettyhome:classerv/classerver")

(complete 95)

(startup "Betty"
	(help @startup-help)
	(prompt "Adding assigns, and startup to Startup")
	(command ("assign BettyHome: %s\n" #classdir))
	(command "assign libs: BettyHome:libs add\n")
	(command "assign libs: BettyHome:classes add\n")
	(command "assign s: BettyHome:s add\n")
	(command "bettyhome:errorserv/errorserver\n")
	(command "bettyhome:classerv/classerver\n")
)

)

(
;Uninstall
(complete 0)

(set #classdir
	(askdir
		(prompt "Where is the directory that contains the Betty directory?")
		(help @askdir-help)
		(default "sys:")
	)
)

(set #classdir (tackon #classdir "Betty"))

(delete #classdir
	(prompt ("Are you sure you want to delete %s?" #classdir))
	(all)
	(confirm)
	(help @delete-help)
	(infos)
)

)

)